# Maintainer: DarkMatterCore <pabloacurielz@gmail.com>

pkgbasename=lwext4
pkgname=switch-${pkgbasename}
pkgver=58bcf89a121b72d4fb66334f1693d3b30e4cb9c5
pkgrel=1
pkgdesc='ext2/ext3/ext4 filesystem library for microcontrollers'
url='https://github.com/gkostka/lwext4'
license=('GPL')
arch=('any')
options=(!strip libtool staticlibs)
makedepends=('devkitA64' 'dkp-toolchain-vars' 'switch-cmake')
groups=('switch-portlibs')
source=(
  "${url}/archive/${pkgver}.zip"
  "${pkgname}-${pkgver}.patch"
)
sha256sums=(
  'bf1de2bd3430d11173ffb6482e2d0d38f991318d8bc9c5dc4051c33b2c407911'
  'c303c83a78a27f42c8474f3a35d05693f120dcd5568e4c2a2399ac9d8c63dd49'
)

prepare() {
  cd "${pkgbasename}-${pkgver}"
  patch -Np1 -i "${srcdir}/${pkgname}-${pkgver}.patch"

  source "${DEVKITPRO}/switchvars.sh"

  mv include lwext4
  mkdir -p include
  mv lwext4 include/lwext4

  make lib_only

  cp -fr build_lib_only/include/lwext4/generated include/lwext4/generated
}

build() {
  cd "${pkgbasename}-${pkgver}"
  make -C build_lib_only
}

package() {
  cd "${pkgbasename}-${pkgver}"

  install -Dm644 build_lib_only/src/liblwext4.a "${pkgdir}${PORTLIBS_PREFIX}/lib/liblwext4.a"
  install -Dm644 LICENSE "${pkgdir}${PORTLIBS_PREFIX}/licenses/${pkgname}/LICENSE"

  cp -fr include "${pkgdir}${PORTLIBS_PREFIX}/include"
  chmod -R u=rwX,go=rX "${pkgdir}${PORTLIBS_PREFIX}/include"
}